Flex与Bison入门系列之高级计算器

2024-06-15

字数统计: 838字 | 阅读时长: 4分

一、简介

这篇文章中我们使用flex和bison制作一个支持基本数学运算和函数调用的计算器。

先来一张图看看效果：

二、词法分析器

为了简单，我们只支持一种数据类型——double，允许定义变量和函数调用。

%{
#include <vector>
#include "parser.hpp"
%}
%%

"+"     { return ADD; }
"-"     { return SUB; }
"*"     { return MUL; }
"/"     { return DIV; }
"("     { return LP; }
")"     { return RP; }
"="     { return ASSIGN; }
","     { return COMMA; }

[0-9]+(\.[0-9]+)? { yylval.NUMBER = atof(yytext); return NUMBER; }

[a-zA-Z_][a-zA-Z0-9]* { yylval.ID = strdup(yytext); return ID; }

\n      { return CR; }
[ \t]   { /*ignore white space*/ }
.       { fprintf(stderr, "lexical error: %s\n", yytext); exit(-1); }

%%

int yywrap(void){ return 0; }

三、语法分析器

语法分析也很简单，这里我们用scopes表示作用域，因为只有一个作用域，所以这是一个全局作用域。

我们把Token定义成union类型的，用于存储数值、字符串和函数的参数。

%{
#include <stdio.h>
#include <string>
#include <vector>
#include <map>
#include <math.h>

#include "funcs.hpp"

static std::map<std::string, double> scopes { { "pi", M_PI }, { "e", M_E } };

int yyerror(char *s);
int yylex();
%}

%code requires {
#include <vector>
}

%define api.value.type union

%token ADD SUB MUL DIV LP RP ASSIGN
%token NUMBER ID
%token COMMA CR

%type <double> NUMBER factor term expr call
%type <char*> ID
%type <std::vector<double>*> parameters

%%

start   : { printf(">"); }
        | start expr CR { printf("%f\n>", $2); }
        | start stmt
        | start CR { printf(">"); }
        ;

stmt    : ID ASSIGN expr CR { scopes[std::string($1)] = $3; printf(">"); }
        ;

expr    : term { $$ = $1; }
        | expr ADD term { $$ = $1 + $3; }
        | expr SUB term { $$ = $1 - $3; }
        ;

term    : factor { $$ = $1; }
        | term MUL factor { $$ = $1 * $3; }
        | term DIV factor { $$ = $1 / $3; }
        ;

factor  : NUMBER { $$ = $1; }
        | LP expr RP { $$ = $2; }
        | SUB factor { $$ = -$2; }
        | ADD factor { $$ = $2; }
        | ID { $$ = scopes[std::string($1)]; }
        | call
        ;

call    : ID LP RP { $$ = handle_call($1, nullptr); }
        | ID LP parameters RP { $$ = handle_call($1, $3); }
        ;

parameters : expr { $$ = new std::vector<double>{$1}; }
        | parameters COMMA expr { $1->push_back($3); $$ = $1; }
        ;

%%

int yyerror(char *s)
{
  fprintf(stderr, "error: %s\n", s);
}

四、内置函数

这里定义一些常用的数学函数，为了简单，我们不考虑自定义函数。

#ifndef TEST_FUNCS_HPP
#define TEST_FUNCS_HPP

#include <string>
#include <vector>
#include <assert.h>
#include <math.h>

using namespace std;

double handle_call(const string &func_name, vector<double> *parameters) {
	#define FUNC_ONE(name) if (func_name == #name) { \
	  assert(parameters->size() == 1); \
	  return name(parameters->operator[](0)); \
	} else

	#define FUNC_TWO(name) if (func_name == #name) { \
	  assert(parameters->size() == 2); \
	  return name(parameters->operator[](0), parameters->operator[](1)); \
	} else

	FUNC_ONE(abs)
	FUNC_ONE(cos)
	FUNC_ONE(sin)
	FUNC_ONE(tan)
	FUNC_ONE(acos)
	FUNC_ONE(asin)
	FUNC_ONE(atan)
	FUNC_ONE(cosh)
	FUNC_ONE(sinh)
	FUNC_ONE(tanh)
	FUNC_ONE(acosh)
	FUNC_ONE(asinh)
	FUNC_ONE(atanh)
	FUNC_ONE(exp)
	FUNC_ONE(log)
	FUNC_ONE(log10)
	FUNC_ONE(exp2)
	FUNC_ONE(expm1)
	FUNC_ONE(log2)
	FUNC_ONE(sqrt)
	FUNC_ONE(logb)
	FUNC_TWO(pow)
	FUNC_ONE(floor)
	FUNC_ONE(round)
	{
		fprintf(stderr, "unknow:%s\n", func_name.c_str());
		exit(-1);
	}
}

#endif //TEST_FUNCS_HPP

五、程序入口

#include "parser.hpp"

int main() {
	return yyparse();
}

六、项目配置

我是使用cmake进行编译的，CMakeLists.txt文件如下：

cmake_minimum_required(VERSION 3.14)
project(test)

set(CMAKE_CXX_STANDARD 11)

find_package(BISON REQUIRED)
find_package(FLEX REQUIRED)

#FLEX_TARGET(scanner test.l ${CMAKE_CURRENT_BINARY_DIR}/test.cpp)

#add_executable(test ${FLEX_scanner_OUTPUTS})

BISON_TARGET(parser ${CMAKE_SOURCE_DIR}/calc.y ${CMAKE_CURRENT_BINARY_DIR}/parser.cpp)
FLEX_TARGET(lexer ${CMAKE_SOURCE_DIR}/calc.l ${CMAKE_CURRENT_BINARY_DIR}/lexer.cpp)
ADD_FLEX_BISON_DEPENDENCY(lexer parser)

include_directories(${CMAKE_CURRENT_BINARY_DIR})
include_directories(${CMAKE_SOURCE_DIR})

add_executable(calc main.cpp ${FLEX_lexer_OUTPUTS} ${BISON_parser_OUTPUTS} funcs.hpp)

七、运行效果

本文作者： killf
本文链接： http://www.killf.info/编程语言/Flex+Bison/Flex与Bison入门系列之高级计算器/
版权声明： 本博客所有文章除特别声明外，均采用 Apache License 2.0 许可协议。转载请注明出处！